/* Includes ------------------------------------------------------------------*/
#include "env.h"

#include <Arduino.h>
#include <Wire.h>
#include <stdlib.h>
#include <WiFi.h>
#include <WiFiMulti.h>

#include "src/epd/epd_cfg.h"
#include "src/epd/epd_driver.h"
#include "src/epd/epd_paint.h"
#include "src/ntp/ntp.h"
#include "src/owm/owm.h"
#include "src/sensor/sensor.h" 
#include "src/touch/gt1151.h"
#include "src/influxdb/influx.h"
#include "src/display/display.h"
#include "src/timedfun/timedfun.h"


#define PIN_SDA 18
#define PIN_SCL 23

#define uS_TO_S_FACTOR 1000000  //Conversion factor for micro seconds to seconds
#define TIME_TO_SLEEP  (60*5)
#define BUTTON_PIN_BITMASK 0x8000


void loop_DRAW(void * pvParameters );
void loop_TOUCH(void * pvParameters );
void loop_MEASURE(void * pvParameters );

/* Global Variables -----------------------------------------------------------*/
static WiFiMulti wifiMulti;
static TwoWire I2C = TwoWire(0);
TaskHandle_t task_measure;
TaskHandle_t task_draw;
TaskHandle_t task_touch;

static NTPtime* ntp = new NTPtime(NTP_URL);
static Sensor* sensor = new Sensor(&I2C);
static GT1151* touch = new GT1151(&I2C);
static OWM* owm[6] = {new OWM(LOCATION_0, OPENWEATHER_API), 
                     new OWM(LOCATION_1, OPENWEATHER_API), 
                     new OWM(LOCATION_2, OPENWEATHER_API), 
                     NULL,NULL,NULL};
static Influx* iflx = new Influx(sensor, owm);//TODO: Add sensor
static TimedFun* tf = new TimedFun();

static bool time_update = true, view_update = true, view_refresh = false;

static const int8_t views_size = 5;
static DisplayWrapper* views[views_size] = {
  new MainDisplay(),
  // new WeatherDisplay(owm[0]),
  new WeatherDisplay(owm[1]),
  new TempDisplay(sensor),
  new AirDisplay(sensor),
  new LightDisplay(sensor),
};
/* IRQ ------------------------------------------------------------------------*/
hw_timer_t * timer = NULL; 
void IRAM_ATTR onSecondTimer() {
  strDateTime* dt = &(ntp->dt);
  dt->second += 1;
  if (dt->second == 60) {
    dt->minute += 1;
    dt->second = 0;
    if(dt->minute % 15 == 0){
      view_refresh =true;
    }
    if (dt->minute == 60) {
      dt->hour += 1;
      dt->minute = 0;
      if (dt->hour == 24) {
        dt->hour = 0;
        dt->minute = 0;
        dt->second = 0;
      }
      view_refresh =true;
    }
    view_update = true;
    time_update = true;

  }
  tf->tick();
}
void IRAM_ATTR onTouch(int8_t contacts, GTPoint *points) {
  if(touch->dev.holding) return;
  if(points[0].y < 125) Display::nextView();
  else Display::prevView();
  view_update = true;
}
/* Setup Functions -----------------------------------------------------------*/
void setup_TOUCH() {
  touch->setHandler(onTouch);
  touch->begin();
}

void setup_WIFI(){
  uint8_t tries = 3;
  WIFI_REGISTER_AP(wifiMulti);
  while(wifiMulti.run() != WL_CONNECTED && tries-- >0) delay(500);
  if(wifiMulti.run() != WL_CONNECTED) Serial.println("WIFI: Not Connected");
  else Serial.println("WIFI: Connected");
}

void setup_TIMER(){
  timer = timerBegin(0, 80, true);
  timerAttachInterrupt(timer, &onSecondTimer, true);
  timerAlarmWrite(timer, 1000000, true);
  timerAlarmEnable(timer);
}

#define REGISTER_TIMEDFUN(name,code) static void name (){code;}
#define REGISTER_TIMEDFUN_CALL(name,min) tf->registerFun(name,min)

REGISTER_TIMEDFUN(SENSOR_MEASURE_TF, do{sensor->measure();}while(0));
REGISTER_TIMEDFUN(OWM_MEASURE_TF, do{uint8_t i = 0;while(owm && owm[i]){owm[i]->update(); ++i;}}while(0));
REGISTER_TIMEDFUN(RECORD_LOCAL_TF, iflx->record_local());
REGISTER_TIMEDFUN(RECORD_WEATHER_TF, iflx->record_weather());
REGISTER_TIMEDFUN(NTP_TF, ntp->updateNTPtime());

void setup_TIMEDFUN() {
  REGISTER_TIMEDFUN_CALL(NTP_TF, 60*60);
  REGISTER_TIMEDFUN_CALL(SENSOR_MEASURE_TF,5); // 5s LOCAL SYNC
  REGISTER_TIMEDFUN_CALL(OWM_MEASURE_TF,5*60); // 5m WEATHER SYNC
  REGISTER_TIMEDFUN_CALL(RECORD_LOCAL_TF,1*60); // 1m LOCAL DB
  REGISTER_TIMEDFUN_CALL(RECORD_WEATHER_TF,5*60); // 5m WEATHER DB
}

void setup_POWER() {
}

/* Setup Functions --------------------------------------------------------------*/
void setup(){
  Serial.begin(115200);
  I2C.begin(PIN_SDA, PIN_SCL);

  setup_POWER();

  Display::setup();
  setup_WIFI();
  ntp->updateNTPtime();
  setup_TOUCH();
  setup_TIMER();
  setup_TIMEDFUN();
  sensor->init();

  iflx->check();
  Display::setViews(views,views_size);
  tf->updateForce();
  tf->setTick(ntp->dt.minute*60 + ntp->dt.second);
  
  xTaskCreatePinnedToCore(
    loop_MEASURE, "Task LMeasure",
    10000, NULL, 1, &task_measure, 0);
  
  xTaskCreatePinnedToCore(
    loop_DRAW, "Task LDraw",
    10000, NULL, 1, &task_draw, 1);
  xTaskCreatePinnedToCore(
    loop_TOUCH, "Task LTouch",
    10000, NULL, 1, &task_touch, 1);

  Serial.println("Completed Setup");
}

/* The main loop -------------------------------------------------------------*/
void loop(){
  delay(5000);
}

void loop_DRAW(void * pvParameters ){
  for(;;){
    if(view_refresh) Display::refresh();
    if(view_update) Display::update(&(ntp->dt));
    if(time_update) Display::drawTime(&(ntp->dt));

    view_refresh = false;
    view_update = false;
    time_update = false;

    vTaskDelay(100);
  }
}

void loop_TOUCH(void * pvParameters ){
  for(;;){
    touch->update();

    vTaskDelay(10);
  }
}
void loop_MEASURE(void * pvParameters ){
  for(;;){
    tf->update();
    vTaskDelay(500);
  }
}


