cowspent/app/build.gradle

plugins {
    id 'com.android.application' version '9.3.2'
    id 'org.jetbrains.kotlin.plugin.serialization' version '2.4.10'
    id 'org.jetbrains.kotlin.plugin.compose' version '2.4.10'
    id 'jacoco'
}

android {
    namespace = 'net.helcel.cowspent'
    compileSdk = 37

    defaultConfig {
        buildConfigField("String", "APP_NAME", "\"Cowspent\"")
        manifestPlaceholders["APP_NAME"] = "Cowspent"
        applicationId "net.helcel.cowspent"
        minSdk = 26
        targetSdk = 37
        versionName project.hasProperty('VERSION_NAME') ? project.property('VERSION_NAME') : "1.4"
        versionCode project.hasProperty('VERSION_CODE') ? project.property('VERSION_CODE').toInteger() : 1
    }

    signingConfigs {
        register("release") {
            try {
                def keystorePropertiesFile = rootProject.file("app/keystore.properties")
                def keystoreProperties = new Properties()
                keystoreProperties.load(new FileInputStream(keystorePropertiesFile))

                keyAlias keystoreProperties['keyAlias']
                keyPassword keystoreProperties['keyPassword']
                storeFile file(keystoreProperties['storeFile'])
                storePassword keystoreProperties['storePassword']
            } catch (FileNotFoundException e) {
                println("File not found: ${e.message}")
            }
        }
    }

    buildTypes {
        debug {
            debuggable true
            initWith(buildTypes.release)
            signingConfig = signingConfigs.debug
            enableUnitTestCoverage true
        }
        release {
            minifyEnabled true
            shrinkResources = true
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
        }
        signedRelease {
            minifyEnabled true
            shrinkResources = true
            initWith(buildTypes.release)
            matchingFallbacks = ['release']
            proguardFiles getDefaultProguardFile('proguard-android-optimize.txt'), 'proguard-rules.pro'
            signingConfig = signingConfigs.getByName("release")
        }
    }

    compileOptions {
        coreLibraryDesugaringEnabled = true
        sourceCompatibility JavaVersion.VERSION_21
        targetCompatibility JavaVersion.VERSION_21
        encoding = 'utf-8'
    }

    buildFeatures {
        viewBinding = true
        buildConfig = true
        compose = true
    }

    testOptions {
        unitTests {
            includeAndroidResources = true
        }
    }

    kotlin {
        jvmToolchain(21)
    }

    lint {
        abortOnError = false
        disable 'MissingTranslation'
        disable 'UsingMaterialAndMaterial3Libraries'
    }

    androidResources {
        generateLocaleConfig = true
    }

    packaging {
        jniLibs.keepDebugSymbols.add("**/*.so")
    }

    dependenciesInfo {
        // Disables dependency metadata when building APKs (for IzzyOnDroid/F-Droid)
        includeInApk = false
        // Disables dependency metadata when building Android App Bundles (for Google Play)
        includeInBundle = false
    }
}

dependencies {
    implementation 'androidx.compose.foundation:foundation:1.12.0'
    implementation 'androidx.compose.runtime:runtime:1.12.0'
    coreLibraryDesugaring 'com.android.tools:desugar_jdk_libs:2.1.5'

    implementation 'androidx.preference:preference-ktx:1.2.1'
    implementation 'androidx.work:work-runtime-ktx:2.11.2'

    implementation 'com.google.zxing:core:3.5.4'
    implementation 'androidx.camera:camera-camera2:1.6.2'
    implementation 'androidx.camera:camera-lifecycle:1.6.2'
    implementation 'androidx.camera:camera-view:1.6.2'
    implementation 'com.github.nextcloud:Android-SingleSignOn:1.1.0'
    implementation 'com.opencsv:opencsv:5.12.0'

    implementation platform('androidx.compose:compose-bom:2026.08.00')
    implementation 'androidx.compose.ui:ui'
    implementation 'androidx.compose.material:material'
    implementation 'androidx.compose.material:material-icons-extended'
    implementation 'androidx.compose.ui:ui-tooling-preview'
    debugImplementation 'androidx.compose.ui:ui-tooling'
    implementation 'androidx.activity:activity-compose:1.13.0'
    implementation 'androidx.activity:activity-ktx:1.13.0'
    implementation 'androidx.security:security-crypto:1.1.0'
    implementation 'androidx.lifecycle:lifecycle-viewmodel-compose:2.11.0'
    implementation "androidx.datastore:datastore-preferences:1.2.1"
    implementation "com.google.crypto.tink:tink-android:1.23.0"

    testImplementation 'junit:junit:4.13.2'
    testImplementation 'io.mockk:mockk:1.14.11'
    testImplementation 'org.robolectric:robolectric:4.16.1'
    testImplementation 'androidx.test:core:1.7.0'
    testImplementation 'org.jetbrains.kotlinx:kotlinx-coroutines-test:1.11.0'
}

tasks.register('jacocoTestReport', JacocoReport) {
    dependsOn 'testDebugUnitTest'

    reports {
        xml.required = true
        html.required = true
    }

    def fileFilter = ['**/R.class', '**/R$*.class', '**/BuildConfig.*', '**/Manifest*.*', '**/*Test*.*']
    def debugTree = fileTree(dir: "${project.layout.buildDirectory.asFile.get()}/intermediates/built_in_kotlinc/debug/compileDebugKotlin/classes", excludes: fileFilter)
    def mainSrc = "${project.projectDir}/src/main/java"

    sourceDirectories.from = files([mainSrc])
    classDirectories.from = files([debugTree])
    executionData.from = fileTree(dir: project.layout.buildDirectory.asFile.get(), includes: [
            'jacoco/testDebugUnitTest.exec', 'outputs/unit_test_code_coverage/debugUnitTest/testDebugUnitTest.exec'
    ])
}